編寫主類Main

在翻轉周邊棋子時，由于要驗證棋子的真實性，代碼稍顯煩瑣。總的說來，就是先獲取上下兩個棋子的id，以及左右存在的棋子的id，然后對棋子進行翻轉。

翻轉完畢后，判斷棋子是否全部變白的代碼也很簡單。代碼如下：

       var grid:Grid;  
        for ( var i:uint = 0, len:uint = grids.length; i < len; i++)  
        {  
                grid = grids[i];  
                //只要發現有一個棋子不是白色，則表明游戲還沒有結束  
                if( grid.isWhite() == false )  
                {  
                       //只要一個為false，則表示游戲還沒有結束  
                }  
        }          
} 

我們的游戲只有一關，因此用戶過關就意味著游戲結束。gameOver函數中，使用了一個文本框來顯示提示信息，由于和程序邏輯沒有聯系，這里略去不提。

至此，主程序的主要代碼介紹完畢，完整的代碼見代碼清單2-4。

代碼清單2-4　FlipIt項目的Main.as文件

package  
{  
  import flash.display.Sprite;  
  import flash.display.StageScaleMode;  
  import flash.display.StageAlign;  
  import flash.events.Event;  
  import flash.events.MouseEvent;  
  import flash.text.TextField;  
  import flash.text.TextFormat;  
  import flash.text.TextFormatAlign;  
    
  [SWF(backgroundColor="#B6B5C1")]  
  public class Main extends Sprite   
  {      
    //使用常量增強程序的靈活性和可讀性  
    private const BLACK:Boolean = false;  
    private const WHITE:Boolean = true;      
    private const GRID_RADIUS:int = 30;      
    private var grid_container:Sprite;  
    private var game_tip:TextField;  
      
    //在數組元素的類型確定的情況下，盡量使用Vector，而不用Array，性能更佳  
    private var grids:Vector.<Grid> = new Vector.<Grid>();      
    private var column_number:uint;  
      
    public function Main():void   
    {  
      init();        
    }  
      
    private function init():void  
    {  
      //設置舞臺屬性，為了自動適應屏幕尺寸，必須設置  
      stage.scaleMode = StageScaleMode.NO_SCALE;  
      stage.align = StageAlign.TOP_LEFT;        
      //創建棋子容器  
      grid_container = new Sprite();  
      addChild(grid_container);        
      //創建文本框，用來顯示游戲結果  
      game_tip = new TextField();  
      var tf:TextFormat = new TextFormat("Droid Serif", 24);  
      tf.align = TextFormatAlign.CENTER;  
      game_tip.defaultTextFormat = tf;  
      game_tip.width = stage.stageWidth;  
      game_tip.y = 500;  
      game_tip.selectable = false;  
      addChild(game_tip);              
      //創建棋盤  
      createMap();        
      //將棋盤屏幕居中放置  
      grid_container.x = (stage.stageWidth - grid_container.width) / 2;        
      grid_container.y = 120;          
      //利用事件流的冒泡機制，只監聽容器的鼠標單擊事件  
      grid_container.addEventListener(MouseEvent.CLICK, onClickHandler);  
    }  
      
    private function createMap():void  
    {  
      var gameMap:Array = new Array();        
      gameMap[0] = [BLACK, WHITE, WHITE, BLACK];  
      gameMap[1] = [WHITE, BLACK, BLACK, WHITE];  
      gameMap[2] = [WHITE, BLACK, BLACK, WHITE];  
      gameMap[3] = [BLACK, WHITE, WHITE, BLACK];  
        
      //列數  
      column_number = 4;  
      //總行數  
      var rowCount:uint = gameMap.length;  
      //臨時變量  
      var rowArray:Array;  
      var i:uint, len:uint;  
      var grid:Grid;  
      //棋子的間距  
      var space:int = 10;        
      //根據數組創建棋盤  
      for ( var row:uint = 0; row < rowCount; row++)  
      {  
        //獲取每一行的數據  
        rowArray = gameMap[row];  
        len = rowArray.length;          
        for ( i = 0; i < len; i++)  
        {  
          //創建Grid，并賦予初始值。GRID_RADIUS常量定義了棋子的尺寸  
          grid = new Grid(rowArray[i], GRID_RADIUS);  
          //計算出棋子在棋盤上的編號  
          grid.id = row * column_number + i;  
          //設置棋子的坐標  
          grid.x = i * (GRID_RADIUS*2 + space);  
          grid.y = row * (GRID_RADIUS*2 + space);  
          grid_container.addChild(grid);  
          //按照編號將棋子保存在數組中，待以后查找  
          grids[grid.id] = grid;  
        }  
      }        
    }  
      
    private function onClickHandler(e:MouseEvent):void  
    {  
      e.stopImmediatePropagation();  
      var grid:Grid = e.target as Grid;  
      //只有單擊的對象是棋子才執行后面的代碼  
      if ( grid == null) return;  
      //翻轉當前單擊的棋子  
      grid.doFlip();  
      //同時翻轉周圍的4個棋子  
      var ids:Array = new Array(grid.id - column_number, grid.id + column_number);  
      //如果棋子是在最左端，則左邊是空的，反之左邊存在棋子  
      if ( grid.id % column_number != 0 )  
      {  
        ids.push(grid.id - 1);  
      }  
      //如果棋子是在最右端，則右邊是空的，反之右邊存在棋子  
      if ( grid.id % column_number != (column_number-1) )  
      {  
        ids.push(grid.id + 1);  
      }  
        
      var totalGrid:int = grids.length;  
        
      for ( var i:uint = 0, len:uint = ids.length; i < len; i++)  
      {  
        var index:int = ids[i];  
          
        if (index <0 || index >= totalGrid) continue;  
          
        grid = grids[index];  
        //上面或下面的棋子可能不存在，需要判斷  
        if ( grid != null )  
        {  
          grid.doFlip();  
        }  
      }        
      if ( isAllWhite() )  
      {  
        //game over  
        gameOver();  
      }  
    }  
      
    private function gameOver():void  
    {  
        grid_container.removeEventListener(MouseEvent.CLICK, onClickHandler);  
      game_tip.text = "順利過關！";  
    }  
      
    private function isAllWhite():Boolean  
    {  
      var grid:Grid;  
      for ( var i:uint = 0, len:uint = grids.length; i < len; i++)  
      {  
        grid = grids[i];  
        if( grid.isWhite() == false )  
        {  
          return false;  
        }  
      }  
      return true;  
    }      
  }    
}