一、自治事務使用情況

無法回滾的審計 ： 一般情況下利用觸發器禁止某些對表的更新等操作時，若記錄日志，則觸發器最后拋出異常時會造成日志回滾。利用自治事務可防止此點。 

避免變異表： 即在觸發器中操作觸發此觸發器的表 

在觸發器中使用ddl 寫數據庫：對數據庫有寫操作（insert、update、delete、create、alter、commit）的存儲過程或函數是無法簡單的用sql來調用的，此時可以將其設為自治事務，從而避免ora-14552（無法在一個查詢或dml中執行ddl、commit、rollback）、ora-14551（無法在一個查詢中執行dml操作）等錯誤。需要注意的是函數必須有返回值，但僅有in參數（不能有out或in/out參數）。 

開發更模塊化的代碼： 在大型開發中，自治事務可以將代碼更加模塊化，失敗或成功時不會影響調用者的其它操作，代價是調用者失去了對此模塊的控制，并且模塊內部無法引用調用者未提交的數據。 

二、Oracle 自制事務 

Oracle 自制事務是指的存儲過程和函數可以自己處理內部事務不受外部事務的影響，用pragma autonomous_transaction來聲明，要創建一個自治事務，您必須在匿名塊的最高層或者存儲過程、函數、數據包或觸發的定義部分中，使用PL/SQL中的PRAGMA AUTONOMOUS_TRANSACTION語句。在這樣的模塊或過程中執行的SQL語句都是自治的。 

結束一個自治事務必須提交一個commit、rollback或執行ddl，否則會產生Oracle錯誤ORA-06519: active autonomous transaction detected and rolled back 。 

三、實例 

------------------------------------------------------------------------- 
-- 存儲過程名：P_DTMS_UPDATE_SAP 
-- 插入數據到T_DATA_DTMS_TAX_EXPORTTOSAP中 
-- 自治事務（pragma autonomous_transaction） 
-- 2012-12-28 
------------------------------------------------------------------------- 
create or replace procedure P_DTMS_UPDATE_SAP( 
i_pkvalue in number, 
i_opcontent_ori in VARCHAR2, 
i_opcontent_dest in VARCHAR2, 
i_source in varchar2 
) 
is 
pragma autonomous_transaction; 
begin 
INSERT INTO T_DATA_DTMS_TAX_EXPORTTOSAP(ID, DTMS_TAX_INVOICE_ID, OPERATE_TYPE, EXPORT_TO_SAP_ORI, EXPORT_TO_SAP_DEST, OPERATE_TIME, SOURCE) 
    VALUES(SEQ_DATA_DTMS_TAX_EXPORTTOSAP.NEXTVAL,i_pkvalue,'update',i_opcontent_ori,i_opcontent_dest,sysdate, i_source); 
commit; 
end; 
------------------------------------------------------------------------- 
-- 觸發器名稱：TRG_INVOICE_EXPORTTOSAP_MODIFY 
-- 當表T_DTMS_TAX_INVOICE做更新操作時觸發，用于對EXPORT_TO_SAP標志位做將1改為0時，拋出異常，回滾修改，即：不允許將EXPORT_TO_SAP從1改為0 
-- 2012-12-28 
------------------------------------------------------------------------- 
create or replace trigger "TRG_INVOICE_EXPORTTOSAP_MODIFY" 
  after update 
  on T_DTMS_TAX_INVOICE 
  for each row 
declare v_pkvalue NUMBER(20); 
        v_opcontent_ori VARCHAR2(50);--修改前的值 
        v_opcontent_dst VARCHAR2(50);--修改后的值 
begin 
  v_pkvalue := :new.id; 
  case when updating then 
    v_opcontent_ori := :old.EXPORT_TO_SAP; 
    v_opcontent_dst := :new.EXPORT_TO_SAP; 
    if v_opcontent_ori = 1 and v_opcontent_dst = 0 then 
      P_DTMS_UPDATE_SAP(v_pkvalue,v_opcontent_ori,v_opcontent_dst,'invoice');--自治事務，調用這個過程的時候它就會獨立于調用它的父事務進行操作 
      RAISE_APPLICATION_ERROR(-20100, 'Cannot Modify T_DTMS_TAX_INVOICE.EXPORT_TO_SAP From 1 To 0.');--拋出異常，RAISE_APPLICATION_ERROR(num,msg)，num在-20000到-20999之間，msg寫你希望拋出的異常。 
    end if; 
  end case; 
end;